build.gradle

import com.xpdustry.toxopid.spec.ModMetadata
import com.xpdustry.toxopid.spec.ModPlatform

plugins {
  id "java"
  id "com.xpdustry.toxopid" version "4.2.0"
  id "net.kyori.indra.publishing" version "4.0.0"
}

def metadata = ModMetadata.fromJson(file("mod.hjson"))

allprojects {
  apply plugin: "java"
  apply plugin: "com.xpdustry.toxopid"
  
  group = "com.xpdustry.${metadata.name}"
  version = metadata.version
  description = metadata.description
  
  sourceSets.main.java.srcDirs = ["src"]
  sourceSets.main.resources.srcDirs = ["resources"]
  toxopid.compileVersion = "v${metadata.minGameVersion}"
  ext.compileVersionV8 = "157"
  ext.arcNet = "com.github.Anuken.Arc:arcnet:${toxopid.compileVersion}" //toxopid.dependencies.arcnet
  
  repositories {
    mavenCentral()
    maven { url "https://maven.xpdustry.com/mindustry" }
    maven { url "https://maven.xpdustry.com/releases" }
    maven { url "https://www.jitpack.io" }
  }

  // Force java 1.8
  compileJava {
    targetCompatibility = JavaVersion.VERSION_1_8
    sourceCompatibility = JavaVersion.VERSION_21
    options.encoding = "UTF-8"
    options.release = 8
    options.compilerArgs += ["-Xlint:-options", "-Xlint:unchecked"]
  }
  
  dependencies {
    annotationProcessor "com.xpdustry:jabel:1.1.0"
  }
}

project(":common") {
  dependencies {
    compileOnly toxopid.dependencies.arcCore
    compileOnly arcNet
  }
}

project(":api") {
  dependencies {
    implementation project(":common")
    compileOnly toxopid.dependencies.arcCore
    compileOnly arcNet
  }
}

project(":client") {
  toxopid.platforms = [ModPlatform.DESKTOP, ModPlatform.ANDROID]

  dependencies {
    implementation project(":common")
    implementation project(":api")
    compileOnly toxopid.dependencies.arcCore
    compileOnly toxopid.dependencies.mindustryCore
  }
  
  jar.from {
     configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
  }

  mergeJar {
    archiveFileName = "${metadata.name}-${project.name}.jar"

    // Includes mod json and icon
    from(rootDir) {
      include "mod.hjson"
      include "icon.png"
    }
  }
	
  // Includes android dex
  build.dependsOn mergeJar
  
  // For testing
  runMindustryDesktop.mods.from(mergeJar)
  task run(dependsOn: runMindustryDesktop) {
    //toxopid.compileVersion = "v${project.compileVersionV8}"
  }
}

project(":server") {
  ext.mainClassName = "com.xpdustry.claj.server.Main"
  toxopid.platforms = [ModPlatform.SERVER]
  toxopid.compileVersion = "v${project.compileVersionV8}"

  dependencies {
    implementation project(":common")
    implementation toxopid.dependencies.arcCore
    implementation arcNet
    implementation toxopid.dependencies.arcHeadless
  }
  
  jar {
    archiveFileName = "${metadata.name}-${project.name}.jar"
    manifest.attributes["Main-Class"] = project.mainClassName
    manifest.attributes["Claj-Version"] = metadata.version
    
    from {
      configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
    }

    //TODO: use arc-lite
    //exclude "arc/assets/**", "arc/audio/**", "arc/input/**", "arc/scene/**", "arc/util/noise/**", "arc/util/viewport/**"
  }
  
  task run(dependsOn: classes, type: JavaExec) {
    mainClass = project.mainClassName
    classpath = sourceSets.main.runtimeClasspath
    standardInput = System.in
    workingDir = temporaryDir
    args 7000 // default port
    jvmArgs "-DClaj-Version=${metadata.version}" // claj version
  }
}

task release(dependsOn: subprojects.build, type: Copy) {
  subprojects.each {
    from it.layout.buildDirectory.dir("libs") 
    include "${metadata.name}-*.jar"
  }
  into layout.buildDirectory.dir("release")
  //into rootDir
}

// To shut up Javadoc
javadoc.options{
    addStringOption("Xdoclint:none", "-quiet")
}


// Publishing
signing {
  def signingKey = findProperty("signingKey")
  def signingPassword = findProperty("signingPassword")
  useInMemoryPgpKeys(signingKey, signingPassword)
}

indra {
  javaVersions {
    target(8)
    minimumToolchain(8)
  }
    
  gpl3OnlyLicense()
  publishReleasesTo("xpdustry", "https://maven.xpdustry.com/releases")

  def repo = metadata.repository.split("/")
  github(repo[0], repo[1]) {
    ci(true)
    issues(true)
    scm(true)
  }

  configurePublications {
    from components.java
    artifact sourcesJar
    artifact javadocJar
  
    pom {
      organization {
        name = "Xpdustry"
        url = "https://www.xpdustry.com"
      }

      developers {
        metadata.author.split(",").each { author ->
          developer {
            id = author.trim()
            url = "https://github.com/${author.trim()}"
          }
        }
      }
    }
  }
}

// I want these to only be included when publishing, not all the time...
task javadocJar(type: Jar, dependsOn: 'javadoc') {
  from javadoc.destinationDir
  archiveClassifier = 'javadoc'
}
task sourcesJar(type: Jar, dependsOn: 'classes') {
  from sourceSets.main.allSource
  archiveClassifier = 'sources'
}