jaxws-samples/build.gradle at master · stefan-kolb/jaxws-samples · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
buildscript {
    repositories {
        jcenter()
    }

    dependencies {
        classpath 'com.bmuschko:gradle-cargo-plugin:2.6.1'
    }
}

wrapper {
    gradleVersion = '5.4.1'
}

allprojects {
    apply plugin: 'java'
    apply plugin: 'idea'
    apply plugin: 'eclipse'

    repositories {
        jcenter()
    }

    dependencies {
        compile group: 'com.sun.xml.ws', name: 'rt', version: '2.3.2'
    }
}

def webProjects() {
    subprojects.findAll { subproject -> subproject.plugins.hasPlugin('war') }
}

gradle.projectsEvaluated {
    configure(webProjects()) {
        apply plugin: 'com.bmuschko.cargo'

        cargo {
            containerId = 'glassfish4x'

            local {
                installer {
                    installUrl = 'https://download.oracle.com/glassfish/4.1.2/release/glassfish-4.1.2.zip'
                    downloadDir = file("$buildDir/download")
                    extractDir = file("$buildDir/extract")
                }
            }
        }

        cargoRunLocal.dependsOn assemble
    }
}