flake.nix

{
  outputs = _: {
    lib = {
      assertBootstrap =
        opts:
        (
          let
            nixpkgs = opts.nixpkgs;
            paths = opts.paths;
            lib = nixpkgs.lib;
            forEachSystem =
              f:
              builtins.foldl' lib.recursiveUpdate { } (
                map f [
                  "aarch64-linux"
                  "aarch64-darwin"
                  "x86_64-linux"
                ]
              );
            lixDrvs = forEachSystem (system: {
              ${system} = nixpkgs.legacyPackages.${system}.lixStatic;
            });
            esc = builtins.fromJSON "\"\\u001b\"";
            red = "${esc}[31m";
            grn = "${esc}[32m";
            rst = "${esc}[0m";
            gry = "${esc}[90m";
            blue = "${esc}[34m";
            magenta = "${esc}[35m";
            bold = "${esc}[1m";
            expected =
              "bootstrap-lix:"
              + builtins.toJSON (
                builtins.builtins.listToAttrs (
                  map (arch: {
                    name = arch;
                    value = lixDrvs.${arch}.outPath;
                  }) (builtins.attrNames lixDrvs)
                )
              );
            pathPos = builtins.unsafeGetAttrPos "paths" opts;
          in
          lib.asserts.assertMsg (paths == expected) (
            "please update assertBootstrap paths:\n"
            + "${bold}${blue}at ${magenta}${pathPos.file}:${builtins.toString pathPos.line}:${builtins.toString pathPos.column}${rst}:\n"
            + "  ${gry}| ...${rst}\n"
            + "  ${gry}|${rst} assert bootstrap.lib.assertBootstrap {\n"
            + "  ${gry}|${rst}   inherit nixpkgs;\n"
            + "  ${gry}|${red}-  paths = ${builtins.toJSON paths};${rst}\n"
            + "  ${gry}|${grn}+  paths = ${builtins.toJSON expected};${rst}\n"
            + "  ${gry}|${rst} };\n"
            + "  ${gry}| ...${rst}"
          )
        );
    };
  };
}