build.gradle.kts

version = "1.14"

dependencies { implementation("org.ow2.asm:asm:9.9.1") }

publishingConventions {
    pluginPortal("${project.group}.${project.name}") {
        implementationClass("org.gradlex.javamodule.moduleinfo.ExtraJavaModuleInfoPlugin")
        displayName("Extra Java Module Info Gradle Plugin")
        description("Add module information to legacy Java libraries.")
        tags("gradlex", "java", "modularity", "jigsaw", "jpms")
    }
    gitHub("https://github.com/gradlex-org/extra-java-module-info")
    developer {
        id.set("jjohannes")
        name.set("Jendrik Johannes")
        email.set("jendrik@gradlex.org")
    }
}

testingConventions { testGradleVersions("6.8.3", "6.9.4", "7.6.5", "8.14.2") }

// Turn off classfile lint as long as we still compile with Java 8
// /org/objectweb/asm/ClassReader.class: Cannot find annotation method 'forRemoval()' in type 'Deprecated'
tasks.compileJava { options.compilerArgs.add("-Xlint:-classfile") }

// === the following custom configuration should be removed once tests are migrated to Java
apply(plugin = "groovy")

tasks.named<GroovyCompile>("compileTestGroovy") { targetCompatibility = "11" } // allow tests to run against 6.x

dependencies { testImplementation("org.spockframework:spock-core:2.3-groovy-4.0") } //
// ====================================================================================