getting-started/website/build.gradle at master · docbook/getting-started · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
buildscript {
  repositories {
    mavenLocal()
    mavenCentral()
    maven { url "https://dev.saxonica.com/maven" }
  }

  configurations.all {
    resolutionStrategy {
      force 'xml-apis:xml-apis:1.4.01',
        "${saxonGroup}:${saxonEdition}:${saxonVersion}",
        "org.xmlresolver:xmlresolver:${xmlresolverVersion}",
        'org.nwalsh:sinclude:4.2.1'
    }
  }

  dependencies {
    classpath group: saxonGroup, name: saxonEdition, version: saxonVersion
    classpath group: 'com.nwalsh', name: 'sinclude', version: '4.2.1'
    classpath group: 'org.docbook', name: 'schemas-docbook', version: docbookVersion
    classpath group: 'org.docbook', name: 'docbook-xslTNG', version: '1.11.0b1'
  }
}

plugins {
  id "java"
  id 'com.nwalsh.gradle.saxon.saxon-gradle' version '0.9.6'
  id 'com.nwalsh.gradle.relaxng.validate' version '0.0.6'
  id 'com.nwalsh.gradle.relaxng.translate' version '0.0.6'
}

import com.nwalsh.gradle.saxon.SaxonXsltTask
import com.nwalsh.gradle.relaxng.validate.RelaxNGValidateTask
import com.nwalsh.gradle.relaxng.translate.RelaxNGTranslateTask
import org.docbook.xsltng.extensions.Register
import com.nwalsh.sinclude.XInclude

repositories {
  mavenLocal()
  mavenCentral()
  maven { url "https://dev.saxonica.com/maven" }
}

configurations.all {
  resolutionStrategy {
    force 'xml-apis:xml-apis:1.4.01',
      "${saxonGroup}:${saxonEdition}:${saxonVersion}",
      "org.xmlresolver:xmlresolver:${xmlresolverVersion}"
  }
}

configurations {
  transform.extendsFrom(implementation)
}

dependencies {
  implementation (
    [group: saxonGroup, name: saxonEdition, version: saxonVersion],
    [group: 'org.docbook', name: 'docbook-xslTNG', version: '1.11.0b1'],
    [group: 'org.docbook', name: 'schemas-docbook', version: docbookVersion]
  )
}

saxon.configure {
  initializer 'org.docbook.xsltng.extensions.Register'
}

defaultTasks "website"

task website(
  dependsOn: ["copy_resources"],
  description: "Build the website",
  group: "website"
) {
  // Just somewhere to hang dependencies
}

// Use gradle to construct tasks for each page
def srcPrefixLen = "${projectDir}/src/xml".length()+1
fileTree(dir: "${projectDir}/src/xml", include: "**/*.xml").each { xml ->
  String html = "${buildDir}/website/" + xml.toString().substring(srcPrefixLen)
  html = html.replaceAll('.xml$', '.html')
  String taskName = xml.toString().substring(srcPrefixLen).replaceAll('/', '_')
  taskName = 'task_' + taskName.replaceAll('.xml$', '')

  Task t = task "${taskName}"(
    type: SaxonXsltTask
  ) {
    inputs.files fileTree("${projectDir}/style")

    input xml
    output html
    stylesheet "${projectDir}/style/website.xsl"
    parameters (
    )
  }
  website.dependsOn t
}

// ============================================================

task copy_docbook_resources() {
  def dbjar = null
  configurations.transform.each { path ->
    if (path.toString().contains("docbook-xslTNG")) {
      dbjar = path
    }
  }

  if (dbjar != null) {
    inputs.file dbjar
    outputs.files fileTree(dir: "${buildDir}/docbook-resources")
  }

  doLast {
    if (dbjar == null) {
      throw new GradleException("Failed to locate DocBook xslTNG jar file")
    }

    copy {
      into "${buildDir}/docbook-resources"
      from ({ zipTree(dbjar.toString()) }) {
        include "org/docbook/xsltng/resources/**"
      }
      eachFile { fileCopyDetails ->
        def originalPath = fileCopyDetails.path
        fileCopyDetails.path = originalPath.replace('org/docbook/xsltng/resources/', '')
      }
      includeEmptyDirs = false
    }
  }
}

task copy_resources(
  dependsOn: ["copy_docbook_resources"]
) {
  inputs.files fileTree(dir: "${buildDir}/docbook-resouces")
  inputs.files fileTree(dir: "${projectDir}/resources")
  inputs.files fileTree(dir: "${projectDir}/src/img")

  doLast {
    copy {
      into "${buildDir}/website"
      from "${buildDir}/docbook-resources"
    }
  }

  doLast {
    copy {
      from "${projectDir}/resources"
      into "${buildDir}/website"
    }
  }

  doLast {
    copy {
      from "${projectDir}/src/img"
      into "${buildDir}/website/img"
    }
  }
}

// ============================================================

task helloWorld() {
  doLast {
    println('Hello, world.')
  }
}