Merge 5416 via sys_libsecp256k1

Author: luke-jr

CMakeLists.txt

@@ -111,6 +111,47 @@ if(WITH_SYSTEM_LEVELDB)
   find_package(LevelDB MODULE REQUIRED)
 endif()  # WITH_SYSTEM_LEVELDB
 
+option(WITH_SYSTEM_LIBSECP256K1 "Build with system libsecp256k1 instead of embedded copy." OFF)
+mark_as_advanced(WITH_SYSTEM_LIBSECP256K1)
+if(WITH_SYSTEM_LIBSECP256K1)
+  find_package(PkgConfig REQUIRED)
+  pkg_check_modules(libsecp256k1 REQUIRED IMPORTED_TARGET libsecp256k1)
+  add_library(secp256k1 ALIAS PkgConfig::libsecp256k1)
+
+  if(NOT (libsecp256k1_HAS_SECP256K1_ELLSWIFT_CREATE AND libsecp256k1_HAS_SECP256K1_XONLY_PUBKEY_PARSE AND libsecp256k1_HAS_SECP256K1_ECDSA_RECOVER AND libsecp256k1_HAS_SECP256K1_SCHNORRSIG_VERIFY))
+    include(CheckSymbolExists)
+    include(CMakePushCheckState)
+    cmake_push_check_state(RESET)
+    string(APPEND CMAKE_REQUIRED_FLAGS " ${libsecp256k1_CFLAGS_OTHER}")
+    list(APPEND CMAKE_REQUIRED_INCLUDES ${libsecp256k1_INCLUDE_DIRS})
+    list(APPEND CMAKE_REQUIRED_LINK_OPTIONS ${libsecp256k1_LDFLAGS})
+    list(APPEND CMAKE_REQUIRED_LIBRARIES ${libsecp256k1_LIBRARIES})
+    unset(missing_modules)
+    macro(check_secp256k1_module module symbol)
+      string(TOUPPER "${symbol}" VAR)
+      set(VAR "libsecp256k1_HAS_${VAR}")
+      unset(${VAR})
+      check_symbol_exists("${symbol}" "secp256k1_${module}.h" ${VAR})
+      if(NOT ${VAR})
+        list(APPEND missing_modules "${module}")
+      endif()
+    endmacro()
+    message(CHECK_START "Checking for required libsecp256k1 modules")
+    list(APPEND CMAKE_MESSAGE_INDENT "  ")
+    check_secp256k1_module(ellswift secp256k1_ellswift_create)
+    check_secp256k1_module(extrakeys secp256k1_xonly_pubkey_parse)
+    check_secp256k1_module(recovery secp256k1_ecdsa_recover)
+    check_secp256k1_module(schnorrsig secp256k1_schnorrsig_verify)
+    list(POP_BACK CMAKE_MESSAGE_INDENT)
+    if(missing_modules)
+      list(JOIN missing_modules ", " missing_modules)
+      message(FATAL_ERROR "System-installed libsecp256k1 lacks these required modules: ${missing_modules}.")
+    endif()
+    message(CHECK_PASS "all were found")
+    cmake_pop_check_state()
+  endif()
+endif()  # WITH_SYSTEM_LIBSECP256K1
+
 option(ENABLE_WALLET "Enable wallet." ON)
 option(WITH_SQLITE "Enable SQLite wallet support." ${ENABLE_WALLET})
 if(WITH_SQLITE)

src/CMakeLists.txt

@@ -22,6 +22,8 @@ endif()  # WITH_SYSTEM_LEVELDB
 
 include(../cmake/minisketch.cmake)
 add_subdirectory(univalue)
+
+if(NOT WITH_SYSTEM_LIBSECP256K1)
 #=============================
 # secp256k1 subtree
 #=============================
@@ -70,6 +72,7 @@ set_target_properties(secp256k1 PROPERTIES
   EXCLUDE_FROM_ALL TRUE
 )
 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
+endif()  # WITH_SYSTEM_LIBSECP256K1
 
 # Set top-level target output locations.
 if(NOT CMAKE_RUNTIME_OUTPUT_DIRECTORY)