feat: Add support for ios_kernel_extension() bazel rule

Author: ilhanraja

apple/internal/ios_rules.bzl

@@ -97,6 +97,7 @@ load(
     "new_iosappclipbundleinfo",
     "new_iosapplicationbundleinfo",
     "new_iosextensionbundleinfo",
+    "new_ioskernelextensionbundleinfo",
     "new_iosframeworkbundleinfo",
     "new_iosimessageapplicationbundleinfo",
     "new_iosimessageextensionbundleinfo",
@@ -2560,13 +2561,221 @@ def _ios_sticker_pack_extension_impl(ctx):
         rule_label = label,
     )
 
+def _ios_kernel_extension_impl(ctx):
+    """Implementation of ios_kernel_extension."""
+    rule_descriptor = rule_support.rule_descriptor(
+        platform_type = "ios",
+        product_type = apple_product_type.kernel_extension,
+    )
+
+    actions = ctx.actions
+    apple_mac_toolchain_info = ctx.attr._mac_toolchain[AppleMacToolsToolchainInfo]
+    apple_xplat_toolchain_info = ctx.attr._xplat_toolchain[AppleXPlatToolsToolchainInfo]
+    bundle_name, bundle_extension = bundling_support.bundle_full_name(
+        custom_bundle_name = ctx.attr.bundle_name,
+        label_name = ctx.label.name,
+        rule_descriptor = rule_descriptor,
+    )
+    bundle_id = bundling_support.bundle_full_id(
+        bundle_id = ctx.attr.bundle_id,
+        bundle_id_suffix = ctx.attr.bundle_id_suffix,
+        bundle_name = bundle_name,
+        suffix_default = ctx.attr._bundle_id_suffix_default,
+        shared_capabilities = ctx.attr.shared_capabilities,
+    )
+    cc_toolchain_forwarder = ctx.split_attr._cc_toolchain_forwarder
+    executable_name = ctx.attr.executable_name
+    features = features_support.compute_enabled_features(
+        requested_features = ctx.features,
+        unsupported_features = ctx.disabled_features,
+    )
+    label = ctx.label
+    platform_prerequisites = platform_support.platform_prerequisites(
+        apple_fragment = ctx.fragments.apple,
+        apple_platform_info = platform_support.apple_platform_info_from_rule_ctx(ctx),
+        build_settings = apple_xplat_toolchain_info.build_settings,
+        config_vars = ctx.var,
+        cpp_fragment = ctx.fragments.cpp,
+        device_families = ctx.attr.families,
+        explicit_minimum_deployment_os = ctx.attr.minimum_deployment_os_version,
+        explicit_minimum_os = ctx.attr.minimum_os_version,
+        features = features,
+        objc_fragment = ctx.fragments.objc,
+        uses_swift = swift_support.uses_swift(ctx.attr.deps),
+        xcode_version_config = ctx.attr._xcode_config[apple_common.XcodeVersionConfig],
+    )
+    predeclared_outputs = ctx.outputs
+    provisioning_profile = ctx.file.provisioning_profile
+    resource_deps = ctx.attr.deps + ctx.attr.resources
+    top_level_infoplists = resources.collect(
+        attr = ctx.attr,
+        res_attrs = ["infoplists"],
+    )
+    top_level_resources = resources.collect(
+        attr = ctx.attr,
+        res_attrs = ["resources"],
+    )
+
+    entitlements = entitlements_support.process_entitlements(
+        actions = actions,
+        apple_mac_toolchain_info = apple_mac_toolchain_info,
+        bundle_id = bundle_id,
+        entitlements_file = ctx.file.entitlements,
+        platform_prerequisites = platform_prerequisites,
+        product_type = rule_descriptor.product_type,
+        provisioning_profile = provisioning_profile,
+        rule_label = label,
+        validation_mode = ctx.attr.entitlements_validation,
+    )
+    # This was added for b/122473338, and should be removed eventually once symbol stripping is
+    # better-handled. It's redundant with an option added in the CROSSTOOL for the
+    # "kernel_extension" feature, but for now it's necessary to detect kext linking so
+    # CompilationSupport.java can apply the correct type of symbol stripping.
+    extra_linkopts = [
+        "-Wl,-kext",
+    ]
+
+    link_result = linking_support.register_binary_linking_action(
+        ctx,
+        cc_toolchains = cc_toolchain_forwarder,
+        entitlements = entitlements.linking,
+        exported_symbols_lists = ctx.files.exported_symbols_lists,
+        extra_linkopts = extra_linkopts,
+        platform_prerequisites = platform_prerequisites,
+        rule_descriptor = rule_descriptor,
+        stamp = ctx.attr.stamp,
+    )
+    binary_artifact = link_result.binary
+    debug_outputs = linking_support.debug_outputs_by_architecture(link_result.outputs)
+
+    processor_partials = [
+        partials.apple_bundle_info_partial(
+            actions = actions,
+            bundle_extension = bundle_extension,
+            bundle_id = bundle_id,
+            bundle_name = bundle_name,
+            executable_name = executable_name,
+            entitlements = entitlements.bundle,
+            label_name = label.name,
+            platform_prerequisites = platform_prerequisites,
+            predeclared_outputs = predeclared_outputs,
+            product_type = rule_descriptor.product_type,
+            rule_descriptor = rule_descriptor,
+        ),
+        partials.binary_partial(
+            actions = actions,
+            binary_artifact = binary_artifact,
+            bundle_name = bundle_name,
+            executable_name = executable_name,
+            label_name = label.name,
+        ),
+        partials.codesigning_dossier_partial(
+            actions = actions,
+            apple_mac_toolchain_info = apple_mac_toolchain_info,
+            apple_xplat_toolchain_info = apple_xplat_toolchain_info,
+            bundle_extension = bundle_extension,
+            bundle_name = bundle_name,
+            entitlements = entitlements.codesigning,
+            label_name = label.name,
+            platform_prerequisites = platform_prerequisites,
+            predeclared_outputs = predeclared_outputs,
+            provisioning_profile = provisioning_profile,
+            rule_descriptor = rule_descriptor,
+        ),
+        partials.debug_symbols_partial(
+            actions = actions,
+            bundle_extension = bundle_extension,
+            bundle_name = bundle_name,
+            debug_dependencies = ctx.attr.deps,
+            dsym_binaries = debug_outputs.dsym_binaries,
+            dsym_info_plist_template = apple_mac_toolchain_info.dsym_info_plist_template,
+            executable_name = executable_name,
+            label_name = label.name,
+            linkmaps = debug_outputs.linkmaps,
+            platform_prerequisites = platform_prerequisites,
+            plisttool = apple_mac_toolchain_info.plisttool,
+            rule_label = label,
+            version = ctx.attr.version,
+        ),
+        partials.resources_partial(
+            actions = actions,
+            apple_mac_toolchain_info = apple_mac_toolchain_info,
+            bundle_extension = bundle_extension,
+            bundle_id = bundle_id,
+            bundle_name = bundle_name,
+            executable_name = executable_name,
+            environment_plist = ctx.file._environment_plist,
+            launch_storyboard = None,
+            platform_prerequisites = platform_prerequisites,
+            resource_deps = resource_deps,
+            rule_descriptor = rule_descriptor,
+            rule_label = label,
+            top_level_infoplists = top_level_infoplists,
+            top_level_resources = top_level_resources,
+            version = ctx.attr.version,
+        ),
+        partials.swift_dylibs_partial(
+            actions = actions,
+            apple_mac_toolchain_info = apple_mac_toolchain_info,
+            binary_artifact = binary_artifact,
+            label_name = label.name,
+            platform_prerequisites = platform_prerequisites,
+        ),
+        partials.apple_symbols_file_partial(
+            actions = actions,
+            binary_artifact = binary_artifact,
+            dependency_targets = [],
+            dsym_binaries = debug_outputs.dsym_binaries,
+            label_name = label.name,
+            include_symbols_in_bundle = False,
+            platform_prerequisites = platform_prerequisites,
+        ),
+    ]
+
+    if platform_prerequisites.platform.is_device:
+        processor_partials.append(
+            partials.provisioning_profile_partial(
+                actions = actions,
+                profile_artifact = provisioning_profile,
+                rule_label = label,
+            ),
+        )
+
+    processor_result = processor.process(
+        actions = actions,
+        apple_mac_toolchain_info = apple_mac_toolchain_info,
+        apple_xplat_toolchain_info = apple_xplat_toolchain_info,
+        bundle_extension = bundle_extension,
+        bundle_name = bundle_name,
+        entitlements = entitlements.codesigning,
+        features = features,
+        ipa_post_processor = ctx.executable.ipa_post_processor,
+        partials = processor_partials,
+        platform_prerequisites = platform_prerequisites,
+        predeclared_outputs = predeclared_outputs,
+        process_and_sign_template = apple_mac_toolchain_info.process_and_sign_template,
+        provisioning_profile = provisioning_profile,
+        rule_descriptor = rule_descriptor,
+        rule_label = label,
+    )
+
     return [
         DefaultInfo(
             files = processor_result.output_files,
         ),
-        IosStickerPackExtensionBundleInfo(),
-        new_iosextensionbundleinfo(),
-        OutputGroupInfo(**processor_result.output_groups),
+        OutputGroupInfo(
+            **outputs.merge_output_groups(
+                link_result.output_groups,
+                processor_result.output_groups,
+            )
+        ),
+        new_appleexecutablebinaryinfo(
+            binary = binary_artifact,
+            cc_info = link_result.cc_info,
+        ),
+        new_ioskernelextensionbundleinfo(),
+        # TODO(b/228856372): Remove when downstream users are migrated off this provider.
+        link_result.debug_outputs_provider,
     ] + processor_result.providers
 
 ios_application = rule_factory.create_apple_rule(
@@ -3199,3 +3408,37 @@ for the stickers should all be in Sticker Pack directories, so `*.stickerpack/*.
         },
     ],
 )
+
+ios_kernel_extension = rule_factory.create_apple_rule(
+    cfg = transition_support.apple_rule_arm64_as_arm64e_transition,
+    doc = "Builds and bundles an iOS Kernel Extension.",
+    implementation = _ios_kernel_extension_impl,
+    predeclared_outputs = {"archive": "%{name}.zip"},
+    attrs = [
+        apple_support.platform_constraint_attrs(),
+        rule_attrs.binary_linking_attrs(
+            deps_cfg = transition_support.apple_platform_split_transition,
+            extra_deps_aspects = [
+                apple_resource_aspect,
+                framework_provider_aspect,
+            ],
+            is_test_supporting_rule = False,
+            requires_legacy_cc_toolchain = True,
+        ),
+        rule_attrs.common_bundle_attrs(
+            deps_cfg = transition_support.apple_platform_split_transition,
+        ),
+        rule_attrs.common_tool_attrs(),
+        rule_attrs.device_family_attrs(
+            allowed_families = rule_attrs.defaults.allowed_families.ios,
+            is_mandatory = False,
+        ),
+        rule_attrs.infoplist_attrs(),
+        rule_attrs.ipa_post_processor_attrs(),
+        rule_attrs.platform_attrs(
+            add_environment_plist = True,
+            platform_type = "ios",
+        ),
+        rule_attrs.signing_attrs(),
+    ],
+)

apple/internal/providers.bzl

@@ -662,6 +662,20 @@ that requirement.
     init = _make_banned_init(provider_name = "IosImessageExtensionBundleInfo"),
 )
 
+IosKernelExtensionBundleInfo, new_ioskernelextensionbundleinfo = provider(
+    doc = """
+Denotes that a target is an iOS kernel extension.
+
+This provider does not contain any fields of its own at this time but is used as
+a "marker" to indicate that a target is specifically an iOS kernel extension
+bundle (and not some other Apple bundle). Rule authors who wish to require that
+a dependency is an iOS kernel extension should use this provider to describe that
+requirement.
+""",
+    fields = {},
+    init = _make_banned_init(provider_name = "IosKernelExtensionBundleInfo"),
+)
+
 IosXcTestBundleInfo, new_iosxctestbundleinfo = provider(
     doc = """
 Denotes a target that is an iOS .xctest bundle.

apple/internal/rule_support.bzl

@@ -141,6 +141,13 @@ _DEFAULT_MACOS_BUNDLE_LOCATIONS = _describe_bundle_locations(
     contents_relative_resources = "Resources",
 )
 
+# Kernel extensions on iOS are not bundled in the same way as other Apple artifacts.
+_DEFAULT_IOS_KERNEL_EXTENSION_BUNDLE_LOCATIONS = _describe_bundle_locations(
+    bundle_relative_contents = "",
+    contents_relative_binary = "",
+    contents_relative_resources = "",
+)
+
 # Descriptors for all possible platform/product type combinations.
 # TODO(b/248317958): Migrate rpaths to args on the linking_support methods.
 _RULE_TYPE_DESCRIPTORS = {
@@ -222,6 +229,16 @@ _RULE_TYPE_DESCRIPTORS = {
                 "@loader_path/Frameworks",
             ],
         ),
+        # ios_kernel_extension
+        apple_product_type.kernel_extension: _describe_rule_type(
+            allowed_device_families = ["iphone", "ipad"],
+            binary_infoplist = False,
+            bundle_extension = ".kext",
+            bundle_locations = _DEFAULT_IOS_KERNEL_EXTENSION_BUNDLE_LOCATIONS,
+            bundle_package_type = bundle_package_type.kernel_extension,
+            product_type = apple_product_type.kernel_extension,
+            requires_signing_for_device = False,
+        ),
         # ios_imessage_application
         apple_product_type.messages_application: _describe_rule_type(
             additional_infoplist_values = {"LSApplicationLaunchProhibited": True},

apple/ios.bzl

@@ -23,6 +23,7 @@ load(
     _ios_framework = "ios_framework",
     _ios_imessage_application = "ios_imessage_application",
     _ios_imessage_extension = "ios_imessage_extension",
+    _ios_kernel_extension = "ios_kernel_extension",
     _ios_static_framework = "ios_static_framework",
     _ios_sticker_pack_extension = "ios_sticker_pack_extension",
 )
@@ -51,6 +52,7 @@ ios_framework = _ios_framework
 ios_imessage_application = _ios_imessage_application
 ios_sticker_pack_extension = _ios_sticker_pack_extension
 ios_imessage_extension = _ios_imessage_extension
+ios_kernel_extension = _ios_kernel_extension
 ios_static_framework = _ios_static_framework
 
 _DEFAULT_TEST_RUNNER = str(Label("//apple/testing/default_runner:ios_default_runner"))

apple/ios.doc.bzl

@@ -26,6 +26,7 @@ load(
     _ios_framework = "ios_framework",
     _ios_imessage_application = "ios_imessage_application",
     _ios_imessage_extension = "ios_imessage_extension",
+    _ios_kernel_extension = "ios_kernel_extension",
     _ios_static_framework = "ios_static_framework",
     _ios_sticker_pack_extension = "ios_sticker_pack_extension",
 )
@@ -57,6 +58,7 @@ ios_extension = _ios_extension
 ios_framework = _ios_framework
 ios_imessage_application = _ios_imessage_application
 ios_imessage_extension = _ios_imessage_extension
+ios_kernel_extension = _ios_kernel_extension
 ios_static_framework = _ios_static_framework
 ios_sticker_pack_extension = _ios_sticker_pack_extension
 ios_test_runner = _ios_test_runner

apple/providers.bzl

@@ -57,6 +57,7 @@ load(
     _IosFrameworkBundleInfo = "IosFrameworkBundleInfo",
     _IosImessageApplicationBundleInfo = "IosImessageApplicationBundleInfo",
     _IosImessageExtensionBundleInfo = "IosImessageExtensionBundleInfo",
+    _IosKernelExtensionBundleInfo = "IosKernelExtensionBundleInfo",
     _IosStaticFrameworkBundleInfo = "IosStaticFrameworkBundleInfo",
     _IosXcTestBundleInfo = "IosXcTestBundleInfo",
     _MacosApplicationBundleInfo = "MacosApplicationBundleInfo",
@@ -109,6 +110,7 @@ IosExtensionBundleInfo = _IosExtensionBundleInfo
 IosFrameworkBundleInfo = _IosFrameworkBundleInfo
 IosImessageApplicationBundleInfo = _IosImessageApplicationBundleInfo
 IosImessageExtensionBundleInfo = _IosImessageExtensionBundleInfo
+IosKernelExtensionBundleInfo = _IosKernelExtensionBundleInfo
 IosStaticFrameworkBundleInfo = _IosStaticFrameworkBundleInfo
 IosXcTestBundleInfo = _IosXcTestBundleInfo
 MacosApplicationBundleInfo = _MacosApplicationBundleInfo