Enabling metrics in argo cd helm + terraform

[talkl]

locals {
  domain = "example.co"
}

resource "helm_release" "argocd" {
  name       = "argocd"
  repository = "https://argoproj.github.io/argo-helm"
  chart      = "argo-cd"
  version    = "7.6.12"
  namespace  = "argocd"

  create_namespace = true

  values = [
    <<-EOF
    configs:
      cm:
        timeout.reconciliation: 15s  # Set the polling interval (e.g., 2 minutes)
    EOF
  ]

  set {
    name  = "notifications.secret.create"
    value = true
  }

  set {
    name  = "notifications.secret.items.slack-token"
    value = var.slack_token
  }

  set {
    name  = "notifications.cm.create"
    value = false
  }

  set {
    name  = "global.domain"
    value = "${var.env_name}-argocd.${local.domain}"
  }

  set {
    name  = "configs.params.server.insecure"
    value = true
  }

  set {
    name  = "server.ingress.enabled"
    value = true
  }

  set {
    name  = "server.ingress.controller"
    value = "aws"
  }

  set {
    name  = "server.ingress.ingressClassName"
    value = "alb"
  }

  set {
    name  = "server.ingress.aws.serviceType"
    value = "ClusterIP"
  }

  set {
    name  = "server.ingress.aws.backendProtocolVersion"
    value = "GRPC"
  }

  set {
    name = "server.ingress.annotations.alb\\.ingress\\.kubernetes\\.io/listen-ports"
    value = "\\[\\{\\\"HTTPS\\\": 80\\}\\, \\{\\\"HTTPS\\\": 443\\}\\]"
  }
  set {
    name = "server.ingress.annotations.alb\\.ingress\\.kubernetes\\.io/scheme"
    value = "internal"
  }
  set {
    name = "server.ingress.annotations.alb\\.ingress\\.kubernetes\\.io/target-type"
    value = "ip"
  }
  set {
    name = "server.ingress.annotations.alb\\.ingress\\.kubernetes\\.io/backend-protocol"
    value = "HTTPS"
  }
  set {
    name = "server.ingress.annotations.alb\\.ingress\\.kubernetes\\.io/ssl-redirect"
    value = 443
  }
}

provider "kubernetes" {
  host                   = var.cluster_endpoint
  cluster_ca_certificate = base64decode(var.cluster_certificate)

  exec {
    api_version = "client.authentication.k8s.io/v1beta1"
    command     = "aws"
    # This requires the awscli to be installed locally where Terraform is executed
    args = ["eks", "get-token", "--cluster-name", var.cluster_name]
  }
}

resource "kubernetes_manifest" "app_of_apps" {
  manifest = {
    "apiVersion" = "argoproj.io/v1alpha1"
    "kind"       = "Application"
    "metadata" = {
      "name"       = "apps"
      "namespace"  = "argocd"
      "finalizers" = ["resources-finalizer.argocd.argoproj.io"]
      "annotations" = {
        "argocd.argoproj.io/sync-id" = "{{.Metadata.SyncId}}"
      }
    }
    "spec" = {
      "destination" = {
        "namespace" = "argocd"
        "server"    = "https://kubernetes.default.svc"
      }
      "project" = "default"
      "source" = {
        "repoURL"        = "https://github.com/example/argocd-clusterconfig.git"
        "path"           = "environments/${var.env_name}"
        "targetRevision" = "main"
        "directory"      = {
          "recurse" = true
        }
      }
      "syncPolicy" = {
        "automated" = {
          "prune"    = true
        }
        "syncOptions" = ["ApplyOutOfSyncOnly=true"]
      }
    }
  }
}

resource "kubernetes_manifest" "argocd_notifications_cm" {
  manifest = {
    "apiVersion" = "v1"
    "data" = {
      "context"         = "argocdUrl: https://${var.env_name}-argocd.example.co"
      "defaultTriggers" = ""
      "service.slack"   = "token: $slack-token"
      "template.app-update-failed" = <<EOT
email:
  subject: Application {{.app.metadata.name}} update has failed.
  message: |
    {{if eq .serviceType "slack"}}:exclamation:{{end}} Application *{{.app.metadata.name}}* update has failed at {{.app.status.operationState.finishedAt}} with error: {{.app.status.operationState.message}}.
    Check the details at: {{.context.argocdUrl}}/applications/{{.app.metadata.name}}.
slack:
  attachments: |
    [{
      "title": "{{ .app.metadata.name}}",
      "title_link": "{{.context.argocdUrl}}/applications/{{.app.metadata.name}}",
      "color": "#E96D76",
      "fields": [
        {
          "title": "Sync Status",
          "value": "Failed",
          "short": true
        },
        {
          "title": "Finished At",
          "value": "{{.app.status.operationState.finishedAt}}",
          "short": true
        },
        {
          "title": "Error",
          "value": "{{.app.status.operationState.message}}",
          "short": true
        },
        {
          "title": "Build number",
          "value": "{{.app.metadata.annotations.build}}",
          "short": true
        }
      ]
    }]
  groupingKey: "{{.app.metadata.name}}-{{.app.status.sync.revision}}-build-{{.app.metadata.annotations.build}}"
  deliveryPolicy: "Update"
  notifyBroadcast: false
EOT
      "template.app-update-degraded" = <<EOT
email:
  subject: Application {{.app.metadata.name}} has entered a degraded state.
  message: |
    {{if eq .serviceType "slack"}}:warning:{{end}} Application *{{.app.metadata.name}}* has entered a degraded state. Current health: {{.app.status.health.status}}.
    Check the details at: {{.context.argocdUrl}}/applications/{{.app.metadata.name}}.
slack:
  attachments: |
    [{
      "title": "{{ .app.metadata.name}}",
      "title_link": "{{.context.argocdUrl}}/applications/{{.app.metadata.name}}",
      "color": "#FF8C00",
      "fields": [
        {
          "title": "Health Status",
          "value": "{{.app.status.health.status}}",
          "short": true
        },
        {
          "title": "Sync Status",
          "value": "{{.app.status.sync.status}}",
          "short": true
        },
        {
          "title": "Build number",
          "value": "{{.app.metadata.annotations.build}}",
          "short": true
        }
      ]
    }]
  groupingKey: "{{.app.metadata.name}}-{{.app.status.health.status}}-build-{{.app.metadata.annotations.build}}"
  deliveryPolicy: "Update"
  notifyBroadcast: false
EOT
      "template.app-update-started" = <<EOT
email:
  subject: Application {{.app.metadata.name}} update has started.
  message: |
    {{if eq .serviceType "slack"}}:rocket:{{end}} Application *{{.app.metadata.name}}* update has started at {{.app.status.operationState.startedAt}}.
    Check the details at: {{.context.argocdUrl}}/applications/{{.app.metadata.name}}.
slack:
  attachments: |
    [{
      "title": "{{ .app.metadata.name}}",
      "title_link": "{{.context.argocdUrl}}/applications/{{.app.metadata.name}}",
      "color": "#0DADEA",
      "fields": [
        {
          "title": "Update Status",
          "value": "In Progress",
          "short": true
        },
        {
          "title": "Started At",
          "value": "{{.app.status.operationState.startedAt}}",
          "short": true
        },
        {
          "title": "Build number",
          "value": "{{.app.metadata.annotations.build}}",
          "short": true
        }
      ]
    }]
  groupingKey: "{{.app.metadata.name}}-{{.app.status.sync.revision}}-build-{{.app.metadata.annotations.build}}"
  deliveryPolicy: "PostAndUpdate"
  notifyBroadcast: false
EOT
      "template.app-update-succeeded" = <<EOT
email:
  subject: Application {{.app.metadata.name}} update has succeeded.
  message: |
    {{if eq .serviceType "slack"}}:white_check_mark:{{end}} Application *{{.app.metadata.name}}* has been successfully updated at {{.app.status.operationState.finishedAt}}.
    Check the details at: {{.context.argocdUrl}}/applications/{{.app.metadata.name}}.
slack:
  attachments: |
    [{
      "title": "{{ .app.metadata.name}}",
      "title_link": "{{.context.argocdUrl}}/applications/{{.app.metadata.name}}",
      "color": "#18be52",
      "fields": [
        {
          "title": "Sync Status",
          "value": "{{.app.status.sync.status}}",
          "short": true
        },
        {
          "title": "Finished At",
          "value": "{{.app.status.operationState.finishedAt}}",
          "short": true
        },
        {
          "title": "Build number",
          "value": "{{.app.metadata.annotations.build}}",
          "short": true
        }
      ]
    }]
  groupingKey: "{{.app.metadata.name}}-{{.app.status.sync.revision}}-build-{{.app.metadata.annotations.build}}"
  deliveryPolicy: "Update"
  notifyBroadcast: false
EOT
      "trigger.on-deployed" = <<EOT
- description: Application is synced and healthy. Triggered once per commit.
  oncePer: app.status.operationState.startedAt
  send:
  - send-slack
EOT
      "trigger.on-update-failed" = <<EOT
- description: Application update has failed
  send:
    - app-update-failed
  when: app.status.operationState.phase in ['Failed', 'Error', 'Unknown']
  oncePer: app.status.operationState.startedAt
EOT
      "trigger.on-update-degraded" = <<EOT
- description: Application update has degraded
  send:
    - app-update-degraded
  when: app.status.health.status == 'Degraded'
  oncePer: app.status.operationState.startedAt
EOT
      "trigger.on-update-started" = <<EOT
- description: Application update has started
  send:
    - app-update-started
  when: app.status.operationState.phase in ['Running', 'InProgress']
  oncePer: app.status.operationState.startedAt
EOT
      "trigger.on-update-succeeded" = <<EOT
- description: Application update has succeeded
  send:
    - app-update-succeeded
  when: app.status.operationState.phase in ['Succeeded'] and app.status.health.status == 'Healthy'
  oncePer: app.status.operationState.startedAt
EOT
    }
    "kind" = "ConfigMap"
    "metadata" = {
      "annotations" = {
        "meta.helm.sh/release-name" = "argocd"
        "meta.helm.sh/release-namespace" = "argocd"
      }
      "labels" = {
        "app.kubernetes.io/component" = "notifications-controller"
        "app.kubernetes.io/instance" = "argocd"
        "app.kubernetes.io/managed-by" = "Helm"
        "app.kubernetes.io/name" = "argocd-notifications-controller"
        "app.kubernetes.io/part-of" = "argocd"
        "app.kubernetes.io/version" = "v2.12.6"
        "helm.sh/chart" = "argo-cd-7.6.12"
      }
      "name" = "argocd-notifications-cm"
      "namespace" = "argocd"
    }
  }

  field_manager {
    name = "example"
    force_conflicts = true
  }
}

I want to expose argocd metrics as an internal ClusterIP service, so I can extract it using Coralogix. How do I expose these?

[frucht-salat]

I recommend using terraform templates (tftpl).

Probably

  set {
    name  = "server.metrics.enabled"
    value = true
  }

  set {
    name  = "controller.metrics.enabled"
    value = true
  }

  set {
    name  = "repoServer.metrics.enabled"
    value = true
  }