Menu_TI.bat

@echo off
:: ======================================================
:: Autor original: Camila Siqueira
:: ======================================================

:: Configurações visuais
title Funcoes - Windows
color 0A
mode con: cols=90 lines=35

:menu
cls
echo ================================================================
echo                 MENU - SELECIONE UMA OPÇÃO
echo ================================================================
echo [1] Verificar e Reparar Disco (CHKDSK)
echo [2] Reparar Arquivos de Sistema (SFC)
echo [3] Limpar Arquivos Temporarios
echo [4] Verificar Erros de Memoria (Diagnostico)
echo [5] Restaurar Sistema
echo [6] Testar Conectividade de Rede (Ping/Teste)
echo [7] Gerenciar Processos (Task Manager)
echo [8] Verificar Atualizacoes do Windows
echo [9] Informacoes do Sistema
echo [10] Limpeza Avancada (DISM + Prefetch)
echo [11] Testar Portas de Rede (PowerShell)
echo [12] Monitor de Desempenho
echo [13] Reinicializar Servicos de Rede
echo [0] Sair
echo ================================================================
set /p opcao="Escolha uma opcao: "

if "%opcao%"=="1" goto chkdsk
if "%opcao%"=="2" goto sfc
if "%opcao%"=="3" goto limpar_temp
if "%opcao%"=="4" goto diagnostico_memoria
if "%opcao%"=="5" goto restaurar_sistema
if "%opcao%"=="6" goto teste_rede
if "%opcao%"=="7" goto gerenciar_processos
if "%opcao%"=="8" goto windows_update
if "%opcao%"=="9" goto info_sistema
if "%opcao%"=="10" goto limpeza_avancada
if "%opcao%"=="11" goto testar_portas
if "%opcao%"=="12" goto monitor_desempenho
if "%opcao%"=="13" goto reiniciar_rede
if "%opcao%"=="0" exit

echo Opcao invalida! Tente novamente.
pause
goto menu

:chkdsk
cls
set /p letra=Digite a letra do disco que deseja verificar (ex: C):
echo Executando CHKDSK na unidade %letra%...
chkdsk %letra%: /f /r
pause
goto menu

:sfc
cls
echo Verificando integridade dos arquivos do sistema...
sfc /scannow
pause
goto menu

:limpar_temp
cls
echo Limpando arquivos temporarios...
del /s /f /q %temp%\*
del /s /f /q C:\Windows\Temp\*
echo Limpeza concluida.
pause
goto menu

:diagnostico_memoria
cls
echo Abrindo Diagnostico de Memoria do Windows...
mdsched.exe
pause
goto menu

:restaurar_sistema
cls
echo Abrindo Restauracao do Sistema...
rstrui.exe
pause
goto menu

:teste_rede
cls
echo Teste de conectividade de rede
set /p destino=Digite o IP ou endereco para testar: 
echo Testando conectividade com %destino%...
ping %destino% -n 4
pause
goto menu

:gerenciar_processos
cls
echo Abrindo Gerenciador de Tarefas...
taskmgr
pause
goto menu

:windows_update
cls
echo Verificando atualizacoes do Windows...
wuauclt /detectnow /updatenow
echo Verificacao solicitada.
pause
goto menu

:info_sistema
cls
echo Informacoes detalhadas do sistema:
systeminfo | more
pause
goto menu

:limpeza_avancada
cls
echo Executando limpeza avancada com DISM...
Dism /Online /Cleanup-Image /ScanHealth
Dism /Online /Cleanup-Image /RestoreHealth
del /s /f /q C:\Windows\Prefetch\*
echo Limpeza avancada concluida.
pause
goto menu

:testar_portas
cls
:loop_portas
set /p host=Digite o IP ou endereco para testar a porta: 
set /p porta=Digite a porta que deseja testar: 
echo Testando porta %porta% em %host%...
powershell -command "Test-NetConnection -ComputerName %host% -Port %porta%"
echo.
set /p continuar=Deseja testar outra porta? (S/N): 
if /I "%continuar%"=="S" goto loop_portas
if /I "%continuar%"=="N" goto menu
goto loop_portas

:monitor_desempenho
cls
echo Abrindo Monitor de Desempenho...
perfmon
pause
goto menu

:reiniciar_rede
cls
echo Reiniciando servicos de rede...
net stop dnscache && net start dnscache
net stop netprofm && net start netprofm
netsh int ip reset
ipconfig /flushdns
echo Servicos de rede reiniciados.
pause
goto menu