Duplicated blank node

[pvankranenburg]

list.json:

{
    "item1": {
        "membersA": [
            "membera1",
            "membera2",
            "membera3"
        ]
    }
}

list.sparql:

PREFIX xyz: <http://sparql.xyz/facade-x/data/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX fx: <http://sparql.xyz/facade-x/ns/>
PREFIX ex: <http://example.org/>

CONSTRUCT {
    ?item_iri
        ex:hasBlankNode [
            ex:hasMemberA ?membera_value ;
        ] ;
}
WHERE {

    SERVICE <x-sparql-anything:> {

        fx:properties fx:location "./list.json" .
        
        ?root a fx:root ;
            ?item_slot ?item_base .

        BIND(IRI(replace(str(?item_slot), str(xyz:), str(ex:))) AS ?item_iri)

        ?item_base xyz:membersA ?membersa_base .
        ?membersa_base fx:anySlot ?membera_value .

    }
}

fx -q list.sparql -o list.ttl

gives as output:

@prefix ex:  <http://example.org/> .
@prefix fx:  <http://sparql.xyz/facade-x/ns/> .
@prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#> .
@prefix xyz: <http://sparql.xyz/facade-x/data/> .

ex:item1  ex:hasBlankNode  [ ex:hasMemberA  "membera3" ] ;
        ex:hasBlankNode  [ ex:hasMemberA  "membera2" ] ;
        ex:hasBlankNode  [ ex:hasMemberA  "membera1" ] .

while I would expect:

@prefix ex:  <http://example.org/> .
@prefix fx:  <http://sparql.xyz/facade-x/ns/> .
@prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#> .
@prefix xyz: <http://sparql.xyz/facade-x/data/> .

ex:item1  ex:hasBlankNode  [
                        ex:hasMemberA  "membera3"  ;
                        ex:hasMemberA  "membera2"  ;
                        ex:hasMemberA  "membera1"  ] .

How to fix this?

[luigi-asprino]

Hi @pvankranenburg

I see the problem, the engine creates a new blank node for each binding.
A simple workaround for the issue is using the fx:bnode function.

PREFIX xyz: <http://sparql.xyz/facade-x/data/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX fx: <http://sparql.xyz/facade-x/ns/>
PREFIX ex: <http://example.org/>

CONSTRUCT {
    ?item_iri ex:hasBlankNode  ?bnode .
    ?bnode ex:hasMemberA ?membera_value .
}
WHERE {

    SERVICE <x-sparql-anything:> {

        fx:properties fx:location "./list.json" .
        
        ?root a fx:root ;
            ?item_slot ?item_base .

        BIND(IRI(replace(str(?item_slot), str(xyz:), str(ex:))) AS ?item_iri)

        

        ?item_base xyz:membersA ?membersa_base .
        ?membersa_base fx:anySlot ?membera_value .



        BIND(fx:bnode(?item_base) AS ?bnode)

    }
}

which yields

@prefix ex:  <http://example.org/> .
@prefix fx:  <http://sparql.xyz/facade-x/ns/> .
@prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#> .
@prefix xyz: <http://sparql.xyz/facade-x/data/> .

ex:item1  ex:hasBlankNode  [ ex:hasMemberA  "membera3" , "membera2" , "membera1" ] .

[pvankranenburg]

Yes. That helped me. Thanks a lot!

I noticed that it is important to create globally unique names for the blank nodes.

E.g. for:

{
    "item1": {
        "membersA": [
            "membera1",
            "membera2",
            "membera3"
        ]
    },
    "item2": {
        "membersA": [
            "membera3",
            "membera4",
            "membera5"
        ]
    }
}

this would work:

PREFIX xyz: <http://sparql.xyz/facade-x/data/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX fx: <http://sparql.xyz/facade-x/ns/>
PREFIX ex: <http://example.org/>

CONSTRUCT {
    ?item_iri ex:hasBlankNode  ?bnode .
    ?bnode ex:hasMemberA ?membera_value .
}
WHERE {

    SERVICE <x-sparql-anything:> {

        fx:properties fx:location "./list.json" .
        
        ?root a fx:root ;
            ?item_slot ?item_base .

        BIND(IRI(replace(str(?item_slot), str(xyz:), str(ex:))) AS ?item_iri)

        ?item_base xyz:membersA ?membersa_base .
        ?membersa_base fx:anySlot ?membera_value .

        BIND(fx:bnode(concat(str(?item_base), str(?item_slot))) AS ?bnode)

    }
}

[luigi-asprino]

Yes, it is. If you want to collapse all items in a single blank node, you need to pass a constant as an argument (identifier) of fx:bnode, e.g. fx:bnode("my bnode"). Otherwise, you pass an argument that uniquely identifies the list (as in your example).

[luigi-asprino]

We can maybe transform this into a discussion and label it as a use case.